Reset Debugger Window in V13

classic Classic list List threaded Threaded
4 messages Options
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

Reset Debugger Window in V13

4D Tech mailing list
I'm working on site and the window settings in the debugger have changed
and I'm not able to use the debugger.


In V14 and 15, the Window Bounds that file is located in its own folder in
Roaming/4D Server/Window Bounds VXX. V13 doesn't use a Window Bounds folder
so I deleted this file, to no avail:

C:\Users\Doug\AppData\Roaming\4D Server\4D Preferences v13.4DPreferences

How do I reset the debugger window settings in V13 (Windows)?


--
Douglas von Roeder
949-336-2902
**********************************************************************
4D Internet Users Group (4D iNUG)
FAQ:  http://lists.4d.com/faqnug.html
Archive:  http://lists.4d.com/archives.html
Options: http://lists.4d.com/mailman/options/4d_tech
Unsub:  mailto:[hidden email]
**********************************************************************
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

RE: Reset Debugger Window in V13

4D Tech mailing list
Doug,

Here is a utility method I use:


C_TEXT($version;$path;$name;$dom;$window)
C_LONGINT($i;$indentOption)



  // --------------------------------------------------------------------------------------------
  // User name (OS): SteveO
  // Date and time: 05/21/15, 07:05:39
  // --------------------------------------------------------------------------------------------
  //
  //Description:
  //
  //This method is used to reset the 4D debugger window when the
  //preferences get screwed up and the window is not drawing correctly
  //
  //
  //Parameters:
  //
  //Return Parameter:
  //
  // --------------------------------------------------------------------------------------------


$version:=Application version


Case of
: ($version="13@")

  // --------------------------------------------------------------------------------------------
  //
  //
  //4D V13
  //
  //
  // --------------------------------------------------------------------------------------------

$path:=Get 4D folder+"4D Preferences v13.4DPreferences"

If (Test path name($path)=Is a document)

$dom:=DOM Parse XML source($path)

ARRAY TEXT($windows;0)

$window:=DOM Find XML element($dom;"preferences/internal_prefs_4d/windows/window";$windows)

For ($i;1;Size of array($windows))

$name:=""
$window:=$windows{$i}

DOM GET XML ATTRIBUTE BY NAME($window;"name";$name)

If ($name="4ddebugger")
DOM REMOVE XML ELEMENT($window)
End if

End for

XML SET OPTIONS($dom;XML Indentation;XML No indentation)

DOM EXPORT TO FILE($dom;$path)

DOM CLOSE XML($dom)

End if

Else

  // --------------------------------------------------------------------------------------------
  //
  //
  //4D V14 & V15
  //
  //
  // --------------------------------------------------------------------------------------------

$path:=Get 4D folder(Active 4D Folder)+\
"4D Window Bounds v"+Substring(Application version;1;2)+Folder separator+\
"coreDialog"+Folder separator+\
"[projectForm]"+Folder separator+\
"4ddebugger.json"

If (Test path name($path)=Is a document)

DELETE DOCUMENT($path)

End if

End case



Hope that helps...


Steve

*********************************************
  Stephen J. Orth                                                
  The Aquila Group, Inc.         Office:  (608) 834-9213
  P.O. Box 690                           Mobile:  (608) 347-6447
  Sun Prairie, WI 53590

  E-Mail:  [hidden email]
*********************************************
-----Original Message-----
From: 4D_Tech [mailto:[hidden email]] On Behalf Of Douglas von Roeder via 4D_Tech
Sent: Monday, June 12, 2017 2:32 PM
To: 4D iNug Technical <[hidden email]>
Cc: Douglas von Roeder <[hidden email]>
Subject: Reset Debugger Window in V13

I'm working on site and the window settings in the debugger have changed
and I'm not able to use the debugger.


In V14 and 15, the Window Bounds that file is located in its own folder in
Roaming/4D Server/Window Bounds VXX. V13 doesn't use a Window Bounds folder
so I deleted this file, to no avail:

C:\Users\Doug\AppData\Roaming\4D Server\4D Preferences v13.4DPreferences

How do I reset the debugger window settings in V13 (Windows)?


--
Douglas von Roeder
949-336-2902

**********************************************************************
4D Internet Users Group (4D iNUG)
FAQ:  http://lists.4d.com/faqnug.html
Archive:  http://lists.4d.com/archives.html
Options: http://lists.4d.com/mailman/options/4d_tech
Unsub:  mailto:[hidden email]
**********************************************************************
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

Re: Reset Debugger Window in V13

4D Tech mailing list
Excellent - thank you!

Works like a charm.


On Mon, Jun 12, 2017 at 12:44 PM, Stephen J. Orth via 4D_Tech <
[hidden email]> wrote:

> $path:=Get 4D folder+"4D Preferences v13.4DPreferences"
>
> If (Test path name($path)=Is a document)
>
> $dom:=DOM Parse XML source($path)
>
> ARRAY TEXT($windows;0)
>
> $window:=DOM Find XML element($dom;"preferences/internal_prefs_4d/windows/
> window";$windows)
>
> For ($i;1;Size of array($windows))
>
> $name:=""
> $window:=$windows{$i}
>
> DOM GET XML ATTRIBUTE BY NAME($window;"name";$name)
>
> If ($name="4ddebugger")
> DOM REMOVE XML ELEMENT($window)
> End if
>
> End for
>
> XML SET OPTIONS($dom;XML Indentation;XML No indentation)
>
> DOM EXPORT TO FILE($dom;$path)
>
> DOM CLOSE XML($dom)
>
> End if
>



--
Douglas von Roeder
949-336-2902
**********************************************************************
4D Internet Users Group (4D iNUG)
FAQ:  http://lists.4d.com/faqnug.html
Archive:  http://lists.4d.com/archives.html
Options: http://lists.4d.com/mailman/options/4d_tech
Unsub:  mailto:[hidden email]
**********************************************************************
Reply | Threaded
Open this post in threaded view
|  
Report Content as Inappropriate

RE: Reset Debugger Window in V13

4D Tech mailing list
In reply to this post by 4D Tech mailing list
The folder you reference is for 4D Server...
is the debugger issue on 4D Server?

If the issue is on the client or in single user then maybe this folder would be more appropriate:
C:\Users\Doug\AppData\Roaming\4D\...

Instead of
C:\Users\Doug\AppData\Roaming\4D Server\....

-Tim




**********************************************************************
4D Internet Users Group (4D iNUG)
FAQ:  http://lists.4d.com/faqnug.html
Archive:  http://lists.4d.com/archives.html
Options: http://lists.4d.com/mailman/options/4d_tech
Unsub:  mailto:[hidden email]
**********************************************************************
Loading...